/* To make life slightly more interesting (and make the game make more sense),
 * the radiation suit has been split into two.  The radiation suit protects
 * against /radiation/ from slimy floors (type "slime") and reduces damage
 * from Baron slimeballs (type "slimeball").  The ceramic suit protects
 * against heat from heated or lava floors (type "fire"), reduces damage from
 * Imp and Mancubus fireballs (type "fireball"), and slightly reduces damage
 * from Revenant tracers and rockets (type "rocket").
 */

// IronFeet descendant that doesn't change the screen color, to give the two
// special suits drowning protection, and also make them both protect against
// generic damaging floors
actor Anachrony_PowerIronFeet : PowerIronFeet
{
	powerup.duration -60
	powerup.color none
}
actor Anachrony_IronFeetGiver : PowerupGiver
{
	-INVENTORY.INVBAR
	+INVENTORY.ALWAYSPICKUP
	+INVENTORY.AUTOACTIVATE
	inventory.maxamount 0
	powerup.color none
	powerup.type Anachrony_PowerIronFeet
}

// Radiation suit
actor Anachrony_TrueRadiationProtection : PowerProtection
{
    damagefactor "slime", 0
    damagefactor "slimeball", 0.5
    powerup.duration -60
    powerup.color "20 FF 00", 0.2
}
actor Anachrony_TrueRadiationProtectionGiver: PowerupGiver
{
	-INVENTORY.INVBAR
	+INVENTORY.ALWAYSPICKUP
	+INVENTORY.AUTOACTIVATE
	inventory.maxamount 0
	powerup.type Anachrony_TrueRadiationProtection
}
actor Anachrony_TrueRadiationSuit : CustomInventory 13307
{
	//$Title True Radiation Suit
	//$Category Powerups
	+COUNTITEM
	+INVENTORY.ALWAYSPICKUP
	+INVENTORY.AUTOACTIVATE
	+INVENTORY.FANCYPICKUPSOUND
	inventory.maxamount 0
    inventory.pickupmessage "Radiation Protection Suit"
	inventory.pickupsound "misc/p_pkup"
  
	// Sprite from the Realm 667 BioSuit, by Ghastly_dragon
    states {
    Spawn:
        BIOS A -1 Bright
        stop
	Pickup:
		TNT1 A 0 A_GiveInventory("Anachrony_IronFeetGiver", 1)
		TNT1 A 0 A_GiveInventory("Anachrony_TrueRadiationProtectionGiver", 1)
		stop
    }
}

// Ceramic suit
actor Anachrony_HeatProtection : PowerProtection
{
    damagefactor "fire", 0
    damagefactor "fireball", 0.5
    damagefactor "rocket", 0.8
    powerup.duration -60
    powerup.color "60 60 60", 0.2
}
actor Anachrony_HeatProtectionGiver: PowerupGiver
{
	-INVENTORY.INVBAR
	+INVENTORY.ALWAYSPICKUP
	+INVENTORY.AUTOACTIVATE
	inventory.maxamount 0
	powerup.type Anachrony_HeatProtection
}
actor Anachrony_CeramicSuit : CustomInventory 13308
{
	//$Title Ceramic Suit
	//$Category Powerups
	+COUNTITEM
	+INVENTORY.ALWAYSPICKUP
	+INVENTORY.AUTOACTIVATE
	+INVENTORY.FANCYPICKUPSOUND
	inventory.maxamount 0
    inventory.pickupmessage "Ceramic Heat Suit"
	inventory.pickupsound "misc/p_pkup"
  
	// Sprite edit by Eevee, based on Doom radsuit
    states {
    Spawn:
        SUI2 A -1 Bright
        stop
	Pickup:
		TNT1 A 0 A_GiveInventory("Anachrony_IronFeetGiver", 1)
		TNT1 A 0 A_GiveInventory("Anachrony_HeatProtectionGiver", 1)
		stop
    }
}
